Derivatives of Logarithm Functions

Supporting materials

If you wish to get a different perspective on the notes below try either of the following textbook sections.

Stewart’s Calculus
	Section 6.4: Derivatives of logarithmic functions

Boelkins/Austin/Schlicker’s Active Calculus
	Section 2.6: Derivatives of Inverse Functions

Review

Logarithms

Since f(x)=(e^x) is a one-to-one function, it has an inverse function. That function is called the natural logarithm function and is denoted
	(f^(-1))(x)=ln(x)

Plot[{E^x,x,Log[x]},{x,-1,8},PlotRange->{-1,8},AspectRatio->1,PlotLabel->"Our friends e^x and ln(x) (and the mirror y=x)",
PlotStyle->{Blue,Dashed,Black},PlotLabels->Placed[Automatic,Above]]

Everything we know about ln(x) comes from the fact that
	y=ln(x) ⟷ x=(e^y)
These functions are “reflections of each other”, across the mirror of y=x.

In general f(x)=(a^x) is a one-to-one function as long as base a is a positive number other than 1. Since it is one-to-one, it has an inverse and that inverse is denoted
	(f^(-1))(x)=(Subscript[log, a])(x)
This means y=(Subscript[log, a])(x) and x=(a^y) are equivalent. 
You can translate any log problem into an exponential problem, and any exponential problem into an equivalent log problem.

Logarithm/Exponential mirrored properties:

(a^x)(a^y)=(a^(x+y)) ⟷ (Subscript[log, a])(u v)=(Subscript[log, a])(u)+(Subscript[log, a])(v)

((a^x)/(a^y))=(a^(x-y)) ⟷ (Subscript[log, a])((u/v))=(Subscript[log, a])(u)-(Subscript[log, a])(v)

((((a^x)))^y) =(a^(x y))⟷ (Subscript[log, a])((u^r))=r (Subscript[log, a])(u)

(a^((Subscript[log, a])(x)))=x⟷(a^x)=(e^(ln((a^x))))=(e^(x ln(a)))

Questions

Let g(x)=2(e^x)-5x.

Find all critical numbers for g(x). Classify each as either a local maximum, a local minimum, or neither.

g[x_]:=2E^x-5x
g'[x]
Plot[{g[x],-5x,2E^x},{x,-1,3},PlotStyle->{Black,Dashed,Dashed},PlotLabels->Placed[Automatic,Above]]
soln=Solve[g'[x]==0,Reals]
N[soln]

Determine where y=g(x) is concave up and where it is concave down.

g[x_]:=2E^x-5x
g''[x]
(* It's always positive, so the function is everywhere concave up. *)

Question

Let h(x)=x (e^(x/3)).

Find the absolute maximum value and the absolute minimum value of h(x) for -4≤x≤4. (Video)

(* h(x)=x (e^(x/3)) is the product of two continuous function: x and (e^(x/3)). Hence it is also continous, and it achieves an absolute maximum and absolute minimum on -4≤x≤4, because its a continuous function on a closed and bounded interval.*)
h[x_]:=x E^(x/3)
h'[x]
Plot[{h[x],h'[x]},{x,-4,4},PlotStyle->{Black,Dashed},PlotLabels->Placed[Automatic,Below]]
soln=Solve[h'[x]==0,Reals]

Question

What is an equivalent way to write g(x)=((((x^2)+1))^(cos(x)))? What is its domain? What is its derivative? (Video)

g[x_]:=(x^2+1)^Cos[x]
h[x_]:=E^(Cos[x]Log[x^2+1])
h'[x]
Plot[{g[x],h[x]},{x,-2,2},PlotStyle->{Black,Dashed}]

Derivative of ln(x)

Let y=ln(x), then x=(e^y). Use implicit differentiation to find ((d y)/(d x)).
	(d/(d x))(x)=(d/(d x))((e^y))
	⟶ 1=(e^y)((d y)/(d x))
	⟶ ((d y)/(d x))=(1/(e^y))=(1/x)

The derivative of ln(x) is

			(d/(d x))(ln(x))=   (1/x)   =    (x^(-1))

Wow! That’s a strange and interesting collision, between the natural log function ln and powers of x. If you recall, there was one power that didn’t fit the power rule of integration,

				∫(x^n)dx=(1/(n+1))(x^(n+1))+C	:

and that's the integrand (x^(-1)). The anti-derivative of every other power is a power -- there’s just this one that didn’t work. What function would serve as its anti-derivative? A log!

Questions

Find any maximum or minimum points to f(x)=x ln(x). (Video)

(* Notice in particular the behavior of this function as x -> 0: it's a battle between x, which is heading to 0, and Log[x], heading to -∞. What's do you think is the limit? *)
f[x_]:=x Log[x]
f'[x]
Solve[f'[x]==0]
Plot[f[x],{x,0,3}]

What is an equation for the tangent line to g(x)=(x^(sin(x))) when x=π/2? (Video)

(* What an interesting looking function! Maybe we could call it the snake function! *)
f[x_]:=x ^Sin[x]
g[x_]:=E^(Sin[x]Log[x])
Plot[{f[x],g[x],1/x,x},{x,0,10Pi},PlotStyle->{Blue,Dashed,{Thin,Black,Dashed},{Thin,Black,Dashed}}]
x0=Pi/2;
fTangent[x_]:=f'[x0](x-x0)+f[x0]
Plot[{f[x],fTangent[x]},{x,0,Pi}]

Let h(x)=ln(-x). What is its domain? What is its derivative? (Video)

f[x_]:=Log[-x]
f'[x]
Plot[{f[x],f'[x]},{x,-3,0}]
Plot[{Log[Abs[x]],1/x},{x,-3,3}]

What is ∫(x^(-1))d x ? (Video)

(* You've got to be a little cautious with any software: we don't appreciate Mathematica's answer in this case - missing an Absolute value (Log[Abs[x]]) and an arbitrary constant. *)
Integrate[x^(-1),x]

Find the area of the region bounded by the x-axis and y=(1/x) for 1≤x≤2. (Video)

Plot[{1/x,0},{x,1,2},Filling->{2}]
Integrate[1/x,{x,1,2}]
Log[2]-Log[1] (* Log[1] is 0, of course! *)
(* So you can think of ln(a) =  (∫_1^a)(x^(-1))d x *)
Integrate[1/x,{x,1,1/2}]
Log[1/2]

Find the area of the region bounded by the x-axis and y=(1/x) for -3≤x≤-1. (Video)

Plot[{1/x,0},{x,-3,-1},Filling->{2},PlotLabel->Integrate[-1/x,{x,-3,-1}]]
 (* Why does that answer make sense, given what we just saw? *)

Find the volume of the solid of revolution obtained by rotating the region bounded by the x-axis and y=1+(1/x) for 1/2≤x≤2. (Video)

volume=Integrate[Pi(1+1/x)^2,{x,1/2,2}]
N[volume]
(* If you're going to do this by hand, you'll probably want to expand out that integrand: *)
Pi Expand[(1+1/x)^2]
(* Then you say the magic words: "the integral of a sum is the sum of the integrals"... *)
Pi (Integrate[1,{x,1/2,2}]+Integrate[1/x^2,{x,1/2,2}]+Integrate[2/x,{x,1/2,2}])

Homework

Weekly assignment 2

IMath problems on derivatives of logarithmic functions