3D Coordinates

MAT 229, Spring 2021

Week 15

Stewart’s Calculus
	Section 12.1: Three-Dimensional Coordinate Systems

Calculus, Volume 3 (Authors: Gilbert Strang and Edwin “Jed” Herman)
	Chapter 9. Vectors in Three Dimensions

2D Coordinates

For points in the plane we have Cartesian coordinates (x,y) and polar coordinates (r,θ). Two numbers are needed to address any point.

(source)

Question

How are locations on Earth’s surface typically represented?		(Video)

(source)

Can you find Cincinnati on the globe above? Can you explain the latitude and longitude given by Mathematica against the values given on the globe?

GeoPosition[Entity["City",{"Cincinnati","Ohio","UnitedStates"}]]

3D Coordinates

Question

What information is needed to locate the position of a flying plane?

In addition to latitude and longitude, we also need altitude -- the three tude-ges. We need to be careful: is altitude the height above the average radius of the Earth, or above the local surface of the Earth? From a mathematical standpoint, it’s probably best to think of it as the height from the center of the Earth....

Cartesian  coordinates in 3D

Start with the x-y plane. Add depth with the z-axis coming out perpendicularly from the plane (that is, at an angle of 90°). A point in space has coordinates (x,y,z) where

z is the distance of the point from the x-y plane

y is the distance of the point from the x-z plane

x is the distance of the point from the y-z plane

Graphics3D[{PointSize[0.03],Point[{2,1,3}],Text[Style[{2,1,3},FontSize->18],{2,1,3},{-1.5,1.5}],Dashing[{0.02}],Line[{{2,1,3},{2,1,0}}],Line[{{2,1,3},{2,0,3}}],Line[{{2,1,3},{0,1,3}}],Text[Style[2,FontSize->18],{1,1,3},{1,1}],Text[Style[1,FontSize->18],{2,0.5,3},{1,1}],Text[Style[3,FontSize->18],{2,1,1.5},{1,1}]},Axes->True,AxesStyle->Thick,AxesLabel->{Style[x,FontSize->18],Style[y,FontSize->18],Style[z,FontSize->18]},PlotRange->{{0,4},{0,4},{0,4}}]

Questions

The equation z=3 is the set of points (x,y,z) with z=3. What is the shape of this set?	(Video)

The equation x=2 is the set of points (x,y,z) with x=2. What is the shape of this set?	(Video)

Give an equation for the plane that is parallel to the y-z plane and is 5 units from it in the positive x direction.

Sketch the equation x+y=3.	(Video)

ParametricPlot3D[{x,3-x,z},{x,0,4},{z,0,4},AxesLabel->{x,y,z},
PlotRange->{{0,4},{0,4},{0,4}}]

What does the fact that the equation is independent of z tell you?

The equation y>1 is the set of points (x,y,z) with y>1. What is the shape of this set?	(Video)

RegionPlot3D[y>1,{x,0,4},{y,0,4},{z,0,4}]

What does the fact that this equation is independent of both x and z tell you?

Distance

Questions

We want to find the distance between (1,2,0) and (2,1,3).

Draw a box with one corner at (1,2,0) and the diagonal corner at (2,1,3).

Graphics3D[
{
PointSize[0.04],
Point[{2,1,3}],
Text[{2,1,3},{2,1,3},{-1.2,1.2}],
Point[{1,2,0}],
Text[{1,2,0},{1,2,0},{-1.2,1.2}],
Line[{{2,1,3},{1,2,0}}]
},
Axes->True,
AxesStyle->Thick,
AxesLabel->{x,y,z},PlotRange->{{1,2},{1,2},{0,3}},BaseStyle->FontSize->18]

What are the dimensions of this box?

What is the distance between the two points?

(Video)

3D distance

The distance between points ((Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])) and ((Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])) is
	(Sqrt[((((Subscript[x, 1])-(Subscript[x, 2])))^2)+((((Subscript[y, 1])-(Subscript[y, 2])))^2)+((((Subscript[z, 1])-(Subscript[z, 2])))^2)]).
Notice how this compares to the distance formula for points in the plane.

“In the plane” might mean in the x-y plane -- that is, when z=0 for the points. In this case, the formula reduces to (Sqrt[((((Subscript[x, 1])-(Subscript[x, 2])))^2)+((((Subscript[y, 1])-(Subscript[y, 2])))^2)]), just as we would hope.

Questions

Consider the triangle whose vertices are (3,-2,-3),  (7,0,1), and (1,2,1).

Graphics3D[
{
PointSize[0.03],
Point[{3,-2,-3}],
Text[Style[{3,-2,-3},FontSize->18],{3,-2,-3},{-1.5,1.5}],
Point[{7,0,1}],
Text[Style[{7,0,1},FontSize->18],{7,0,1},{-1.5,1.5}],
Point[{1,2,1}],
Text[Style[{1,2,1},FontSize->18],{1,2,1},{-1.5,1.5}],
Line[{{7,0,1},{3,-2,-3}}],
Line[{{7,0,1},{1,2,1}}],
Line[{{1,2,1},{3,-2,-3}}]
},
Axes->True,
AxesStyle->Thick,
AxesLabel->{Style[x,FontSize->18],Style[y,FontSize->18],Style[z,FontSize->18]},PlotRange->{{1,7},{-2,2},{-3,1}}]

Is it a right triangle?

distance3D[p1_,p2_]:=Norm[p1-p2]
distance3D[{3,-2,-3},{7,0,1}]
distance3D[{3,-2,-3},{1,2,1}]
distance3D[{1,2,1},{7,0,1}]

Is it an isosceles triangle?

(Video)

Questions

Consider the set of points (x,y,z) that are a distance of 2 from the origin (0,0,0).

What is an equation that x,y,z must satisfy for (x,y,z) to be in this set?

What is this shape?

ContourPlot3D[x^2+y^2+z^2==4,{x,-3,3},{y,-3,3},{z,-3,3}]

(Video)

Spheres

From the distance formula, we can deduce an equation of the sphere centered on C(a,b,c) of radius r. The sphere is the set of all points equidistant, at a distance r, from the center.

That is, a sphere is the set of points that are the same distance, the radius, from a specified point -- the sphere’s center. If the radius is r and the center has coordinates (a,b,c), then this is an equation for the sphere:
	(((x-a))^2)+(((y-b))^2)+(((z-c))^2)=(r^2).

Questions

The equation (((x-2))^2)+(y^2)+(((z+3))^2)=4 represents a particular sphere.

What is its center?

Let’s re-write this equation:	 (((x-2))^2)+(((y-0))^2)+(((z+3))^2)=(2^2)

What is its radius?

Describe its intersections with each of the coordinate planes.

Show[
ContourPlot3D[(x-2)^2+y^2+(z+3)^2==2^2,{x,0,4},{y,-2,2},{z,-5,0}],
ParametricPlot3D[{x,0,z},{x,0,4},{z,-5,0}],
ParametricPlot3D[{0,y,z},{y,-2,2},{z,-5,0}],
ParametricPlot3D[{x,y,0},{x,0,4},{y,-2,2}],
Axes->True,
AxesLabel->{Style[x,FontSize->18],Style[y,FontSize->18],Style[z,FontSize->18]},PlotRange->{{0,4},{-2,2},{-5,0}},BoxRatios->Automatic
]

(Video)

The equation (x^2)+(y^2)+(z^2)+2x-4y-10z=0 represents a sphere.

radius=Sqrt[30];
ContourPlot3D[
x^2+y^2+z^2+2x-4y-10z==0,
{x,-1-radius,-1+radius},{y,2-radius,2+radius},{z,5-radius,5+radius},
Axes->True,
AxesLabel->{x,y,z},
PlotRange->{{-1-radius,-1+radius},{2-radius,2+radius},{5-radius,5+radius}},BaseStyle->FontSize->18
]

What is its center?

What is its radius?

(Video)

Homework

IMath problems on the Three-Dimensional Coordinate Systems