Polar Coordinate Calculus

MAT 229, Spring 2021

Week 15

Stewart’s Calculus
	Section 10.4: Areas and Lengths in Polar Coordinates

Review

Relations between Cartesian coordinates (x,y) and polar coordinates (r,θ).
	x=r cos(θ)
y=r sin(θ)
and
	(r^2)=(x^2)+(y^2)
tan(θ)=(y/x)

xx=4;
yy=4;
rr=3;
θθ=ArcTan[yy/xx];Graphics[{PointSize[0.02],Point[{xx,yy}],Circle[{0,0},1,{0,θθ}],Dashed,Line[{{xx,0},{xx,yy},{0,0}}],Text[x,{xx/2,-0.3}],Text[y,{xx+0.3,yy/2}],Text[r,{xx/2-0.3,yy/2+0.3}],Text[θ,1.3{Cos[θθ/2],Sin[θθ/2]}],Text[{x,y},{xx,yy+1},{0,1}],Text[{r,θ},{xx,yy+0.5},{0,1}]},Axes->True,Ticks->None,BaseStyle->FontSize->18,PlotRange->{{-2,5},{-2,5}}]

Area

In Cartesian coordinates, area was approximated using rectangles. In polar coordinates, area is approximated using circular wedges.

Question

What is the area of a wedge from a circle of radius r subtended by an angle θ?	(Video)

Graphics[{Yellow,Disk[{0,0},1,{0,π/4}],Black,Dashing[{0.01}],Circle[{0,0},1],Dashing[{}],Thick,Line[{{1,0},{0,0},{1/(Sqrt[2]),1/(Sqrt[2])}}],Circle[{0,0},1,{0,Pi/4}],Thin,Circle[{0,0},.2,{0,Pi/4}],Text[Style[θ,FontSize->14],.3{Cos[π/8],Sin[π/8]}],Text[Style[r,FontSize->14],.5{Cos[Pi/4],Sin[Pi/4]},{1,-1}]}]

Area approximation

Given a curve r=f(θ),a≤θ≤b, subdivide the interval [a,b] into n subintervals of equal width Δ θ=((b-a)/n) with a=(Subscript[θ, 0]),(Subscript[θ, 1]),(Subscript[θ, 2]),…,(Subscript[θ, n-1]),(Subscript[θ, n])=b. Approximate the region bounded by f=f(θ),(Subscript[θ, k])≤θ≤(Subscript[θ, k+1]) with the circular wedge of radius r=f((Subscript[θ, k+1])) and angle Δ θ. Sum the areas of these wedges to get an approximation for the entire region.

area[exp_,{t_,tmin_,tmax_,n_}]:=Module[{dt,r,plot,areaApprox,wedgeList,shade=GrayLevel[0.8]},
dt=N[Abs[tmax-tmin]/n];
r[θ_]:=exp/.{t->θ};
wedgeList=Table[Disk[{0,0},r[tmin+k dt],{tmin+(k-1) dt,tmin+(k) dt}],{k,n}];
areaApprox=Sum[(r[tmin+k dt])^2 dt/2,{k,n}];
plot=PolarPlot[r[θ],{θ,tmin,tmax},PlotLabel->areaApprox];
Show[plot,Graphics[Join[{shade},wedgeList]],
plot]
]
Manipulate[area[2+Cos[t],{t,0,Pi,n}],{n,1,100,1}]

Area formula

The area bounded by r=f(θ),a≤θ≤b is
	(∫_a^b)(1/2)(r^2)d θ=(∫_a^b)(1/2)((f(θ))^2)d θ

Question

What is the area enclosed by the closed curve r=1-sin(θ)?		(Video)

Manipulate[area[1-Sin[t],{t,0,2Pi,n}],{n,1,100,1}]

Questions

Consider the petaled rose r=cos(3θ).

p1=PolarPlot[Cos[3θ],{θ,0,π},AspectRatio->1];
p2=PolarPlot[Cos[3θ],{θ,-π/6,π/6},AspectRatio->1, PlotStyle->Red];
Show[p1,p2]

This is a closed curve. Starting at θ=0, how far do we need to go with θ before the curve starts repeating?

Find a range of values of θ that give one petal of the rose.

What is the area enclosed by one petal?

Manipulate[area[Cos[3t],{t,-π/6,π/6,n}],{n,1,100,1}]
Integrate[1/2 Cos[3t]^2,{t,-π/6,π/6}]
N[%]

(Video)

Questions

We are interested in the area that is outside the circle r=1 but inside circle r=(Sqrt[2])sin(θ).

p1=PolarPlot[1,{θ,0,2π},AspectRatio->1.2];
p2=PolarPlot[Sqrt[2]Sin[θ],{θ,0,2π}, PlotStyle->Red];
Show[p1,p2]

What are the points of intersection for these two curves?

What range of values of θ will sweep out the area inside the second circle between these two points of intersection?

What is the area inside the second circle but outside the first one?

Integrate[1/2((Sqrt[2]Sin[t])^2-1^2),{t,Pi/4,3Pi/4}]

(Video)

Polar curves as parametric equations

Given a polar curve r=f(θ),a≤θ≤b, use the equations
	x=r cos(θ)
y=r sin(θ)
to get parametric equations for the curve.

Questions

Write each polar equation as parametric equations.

r=2,0≤θ≤2π

r=cos(θ),–π/2≤θ≤π/2

PolarPlot[Cos[th],{th,-Pi/2,Pi/2},AspectRatio->1]
ParametricPlot[{Cos[th]^2,Cos[th]Sin[th]},{th,-Pi/2,Pi/2},AspectRatio->1]

r=1-2cos(θ),0≤θ≤2π

PolarPlot[1-2Cos[th],{th,0,2Pi}]
ParametricPlot[{(1-2Cos[th])Cos[th],(1-2Cos[th])Sin[th]},{th,0,2Pi},AspectRatio->1.2]

(Video)

Questions

Using parametric equations for r=sin(θ),0≤θ≤π, find the points in polar coordinates for the points on the curve with

Horizontal tangents

Vertical tangents

(Video)

Questions

For general r=f(θ) find a formula for ((d y)/(d x)) in terms of r and θ.

Use the formula to find the slope of the tangent line to r=cos(3θ) at θ=2π/3.

th0=2Pi/3
x[t_]:=Cos[3t]Cos[t]
y[t_]:=Cos[3t]Sin[t]
p1=ParametricPlot[{x[t],y[t]},{t,0,Pi},AspectRatio->1];
dydx[t_]:=y'[t]/x'[t]
tangentLine[t_]:=y[th0]+dydx[th0](x[t]-x[th0])
p2=ParametricPlot[{x[t],tangentLine[t]},{t,th0-Pi/12,th0+Pi/12},PlotLabel->StringJoin["θ =",ToString[th0,InputForm]],
PlotRange->{{-1,1},{-1,1}}];
Show[p2,p1]

Here it is, wrapped into a Manipulate command:

Manipulate[
Module[{},
tangentLine[t_]:=y[θ]+dydx[θ](x[t]-x[θ]);
p2=ParametricPlot[{x[t],tangentLine[t]},{t,θ-Pi/12,θ+Pi/12},PlotLabel->StringJoin["θ =",ToString[θ,InputForm]],
PlotRange->{{-1,1},{-1,1}}];
Show[p2,p1]
],{θ,0.0001,Pi-.0001}
]

(Video)

Questions

Recall that, given parametric equations for a curve
	x=x(t),y=y(t), a≤t≤b,
the length of the parametric curve is
	(∫_a^b)(Sqrt[((x'(t))^2)+((y'(t))^2)])d t.

For general r=f(θ),a≤θ≤b find a formula for its length by first writing it as parametric equations.		(Video)

Use the formula to find the length of the curve r=sin(θ),0≤θ≤π/2.	(Video)

th0=Pi/2;
f[t_]:=Sin[t]
x[t_]:=f[t]Cos[t]
y[t_]:=f[t]Sin[t]
length[t_]:=Sqrt[x'[t]^2+y'[t]^2]
length[t_]:=Sqrt[f'[t]^2+f[t]^2]
thisLength=NIntegrate[length[t],{t,0,th0}];
p1=ParametricPlot[{x[t],y[t]},{t,0,th0},
PlotStyle->Red,PlotLabel->StringJoin["Length =",ToString[thisLength,InputForm]],
PlotRange->{{-1,1},{-1,1}}]

Here it is as a manipulate command:

Manipulate[
Module[{},
thisLength=NIntegrate[length[t],{t,0,θ}];
p1=ParametricPlot[{x[t],y[t]},{t,0,2Pi},PlotLabel->StringJoin["Length =",ToString[thisLength,InputForm]]];
p2=ParametricPlot[{x[t],y[t]},{t,0,θ},
PlotStyle->{Thickness[.02],Red},
PlotRange->{{-1,1},{-1,1}}];
Show[p1,p2]
],{θ,.0001,Pi}
]

Application: optimal orange peeling...

Prof. Long and a few others are writing a paper about how best to peel an orange (well, it actually started out as the optimal way to create roads on a spherical planet, so that every point was within a distance D of a road, and the road was of shortest length -- but, to make it more practical, let’s think of it as peeling an orange with the shortest peel and width D).

Here is a curve that reminds me of our solution to the orange peeling problem, if your orange is flat and of infinite extent (aren’t all of your oranges flat and infinite?). That reminds me of a joke about modeling elephants:  “assume small spherical elephants...”:) Consider “the Involute of a circle”: r^2=θ^2+1

p1=PolarPlot[Sqrt[θ^2+1],{θ,0,6π},AspectRatio->1];
p2=PolarPlot[-Sqrt[θ^2+1],{θ,0,6π},AspectRatio->1, PlotStyle->Red];
Show[p1,p2]

Maybe, however, my hero Archimedes may have beaten us to the solution. I’m sure that he peeled a lot of oranges. The spiral of Archimedes: r = a θ

p1=PolarPlot[θ/(2π),{θ,0,6π},AspectRatio->1];
p2=PolarPlot[-θ/(2π),{θ,0,6π},AspectRatio->1, PlotStyle->Red];
Show[p1,p2]

Nonetheless I hold out hope for our peeling, which is piecewise half-circles:

f[t_]=-Cos[t];
g[t_]=Sin[t];
p1=Show[
Table[
ParametricPlot[
{n (f[t]-(1+(-1)^n)/(2n)),n*g[t]},
{t,(n-1) Pi,n Pi},
Ticks->None,
PlotRange->{{-6,6},{-6,6}},
PlotStyle->Red
],
{n,1,5,1}
]
]

Here it is as a manipulate command:

Manipulate[
Module[{cx,cy,n},
n=Ceiling[time/Pi];
cx=n (f[time]-(1+(-1)^n)/(2n));
cy=n*g[time];
Show[
p1,
ParametricPlot[{f[t]-1,g[t]},{t,-Pi,0},PlotStyle->Green],
Table[
ParametricPlot[
{(n+1) (f[t]-(1+(-1)^n)/(2(n+1))),(n+1)g[t]},
{t,(n-1) Pi,Min[n Pi,time]},
Ticks->None,
PlotRange->{{-6,6},{-6,6}},
PlotStyle->Green
],
{n,1,Ceiling[time/Pi],1}
],
ParametricPlot[{f[t]+cx,g[t]+cy},{t,0,2Pi}]
]
],{time,0.01,5*Pi}
]

Homework

IMath problems on the Calculus of Polar Coordinates