Section 10.4: Polar Coordinates

Review

Questions

What are the relations between Cartesian coordinates (x,y) and polar coordinates (r,θ)?

Area

In Cartesian coordinates, area was approximated using rectangles. In polar coordinates, area is approximated using circular wedges.

Question

What is the area of a wedge from a circle of radius r subtended by an angle θ.

Graphics[{Yellow,Disk[{0,0},1,{0,π/4}],Black,Dashing[{0.01}],Circle[{0,0},1],Dashing[{}],Thick,Line[{{1,0},{0,0},{1/(Sqrt[2]),1/(Sqrt[2])}}],Circle[{0,0},1,{0,Pi/4}],Thin,Circle[{0,0},.2,{0,Pi/4}],Text[Style[θ,FontSize->14],.3{Cos[π/8],Sin[π/8]}],Text[Style[r,FontSize->14],.5{Cos[Pi/4],Sin[Pi/4]},{1,-1}]}]

Area approximation

Given a curve r=f(θ),a≤θ≤b, subdivide the interval [a,b] into n subintervals of equal width Δ θ=((b-a)/n) with a=(Subscript[θ, 0]),(Subscript[θ, 1]),(Subscript[θ, 2]),…,(Subscript[θ, n-1]),(Subscript[θ, n])=b. Approximate the region bounded by f=f(θ),(Subscript[θ, k])≤θ≤(Subscript[θ, k+1]) with the circular wedge of radius r=f((Subscript[θ, k+1])) and angle Δ θ. Sum the areas of these wedges to get an approximation for the entire region.

area[exp_,{t_,tmin_,tmax_,n_}]:=Module[{dt,r,plot,areaApprox,wedgeList,shade=GrayLevel[0.8]},
dt=N[Abs[tmax-tmin]/n];
r[θ_]:=exp/.{t->θ};
wedgeList=Table[Disk[{0,0},r[tmin+k dt],{tmin+(k-1) dt,tmin+(k) dt}],{k,n}];
areaApprox=Sum[(r[tmin+k dt])^2 dt/2,{k,n}];
plot=PolarPlot[r[θ],{θ,tmin,tmax},PlotLabel->areaApprox];
Show[plot,Graphics[Join[{shade},wedgeList]],
plot]
]

Manipulate[area[2+Cos[t],{t,0,Pi,n}],{n,1,100,1}]

Area formula

The area bounded by r=f(θ),a≤θ≤b is
	(∫_a^b)(1/2)((f(θ))^2)d θ

Question

What is the area enclosed by the closed curve r=1-sin(θ)?

Manipulate[area[1-Sin[t],{t,0,2Pi,n}],{n,1,100,1}]

Questions

Consider the petaled rose r=cos(3θ).

p1=PolarPlot[Cos[3θ],{θ,0,π},AspectRatio->1];
p2=PolarPlot[Cos[3θ],{θ,-π/6,π/6},AspectRatio->1, PlotStyle->Red];
Show[p1,p2]

This is a closed curve. Starting at θ=0, how far do we need to go before with θ before the curve starts repeating?

Find a range of values of θ that give one petal of the rose.

What is the area enclosed by one petal?

Manipulate[area[Cos[3t],{t,-π/6,π/6,n}],{n,1,100,1}]
Integrate[1/2 Cos[3t]^2,{t,-π/6,π/6}]
N[%]

Questions

We are interested in the area that is outside the circle r=1 but inside circle r=(Sqrt[2])sin(θ).

p1=PolarPlot[1,{θ,0,2π},AspectRatio->1.5];
p2=PolarPlot[Sqrt[2]Sin[θ],{θ,0,2π}, PlotStyle->Red];
Show[p1,p2]

What are the points of intersection for these two curves?

What range of values of θ will sweep out the area inside the second circle between these two points of intersection?

What is the area inside the second circle but outside the first one?

Integrate[1/2((Sqrt[2]Sin[t])^2-1^2),{t,Pi/4,3Pi/4}]
(* Figure 5, p. 710 *)
2Integrate[1/2((3Sin[t])^2-(1+Sin[t])^2),{t,Pi/6,Pi/2}]

Questions

Using the same two circles above
	r=1
r=(Sqrt[2])sin(θ),
what is the area of the region inside the first circle r=1, and outside the second circle r=(Sqrt[2])sin(θ)?

(* Half the circle, plus twice the area from angle 0 to Pi/4: *)
Pi/2+2*Integrate[1/2((1^2-Sqrt[2]Sin[t])^2),{t,0,Pi/4}]
Simplify[%]

What is the area of the region that is inside both these two circles?

(* The area of the circle minus the part found earlier! *)
(Pi/2)-Integrate[1/2((Sqrt[2]Sin[t])^2-1^2),{t,Pi/4,3Pi/4}]

Polar curves as parametric equations

Given a polar curve r=f(θ),a≤θ≤b, use the equations
	x=r cos(θ)
y=r sin(θ)
to get parametric equations for the curve.

Questions

Write each polar equation as parametric equations.

r=2,0≤θ≤2π

r=cos(θ),–π/2≤θ≤π/2

PolarPlot[Cos[th],{th,0,2Pi},AspectRatio->1.2]
ParametricPlot[{Cos[th]^2,Cos[th]Sin[th]},{th,0,2Pi},AspectRatio->1.2]

r=1-2cos(θ),0≤θ≤2π

PolarPlot[1-2Cos[th],{th,0,2Pi}]
ParametricPlot[{(1-2Cos[th])Cos[th],(1-2Cos[th])Sin[th]},{th,0,2Pi},AspectRatio->1.2]

Questions

Using parametric equations for r=sin(θ),0≤θ≤π, find the points in polar coordinates for the points on the curve with

Horizontal tangents

Vertical tangents

Questions

For general r=f(θ) find a formula for ((d y)/(d x)) in terms of r and θ.

Use the formula to find the slope of the tangent line to r=cos(3θ) at θ=2π/3.

th0=2Pi/3
x[t_]:=Cos[3t]Cos[t]
y[t_]:=Cos[3t]Sin[t]
p1=ParametricPlot[{x[t],y[t]},{t,0,Pi},AspectRatio->1];
dydx[t_]:=y'[t]/x'[t]
tangentLine[t_]:=y[th0]+dydx[th0](x[t]-x[th0])
p2=ParametricPlot[{x[t],tangentLine[t]},{t,th0-Pi/12,th0+Pi/12},PlotLabel->StringJoin["θ =",ToString[th0,InputForm]],
PlotRange->{{-1,1},{-1,1}}];
Show[p2,p1]

Here it is, wrapped into a Manipulate command:

Manipulate[
Module[{},
tangentLine[t_]:=y[θ]+dydx[θ](x[t]-x[θ]);
p2=ParametricPlot[{x[t],tangentLine[t]},{t,θ-Pi/12,θ+Pi/12},PlotLabel->StringJoin["θ =",ToString[θ,InputForm]],
PlotRange->{{-1,1},{-1,1}}];
Show[p2,p1]
],{θ,0.0001,Pi-.0001}
]

Questions

For general r=f(θ),a≤θ≤b find a formula for its length by first writing it as parametric equations.

Use the formula to find the length of the curve r=sin(θ),0≤θ≤π/2.

th0=Pi/2;
f[t_]:=Sin[t]
x[t_]:=f[t]Cos[t]
y[t_]:=f[t]Sin[t]
length[t_]:=Sqrt[x'[t]^2+y'[t]^2]
length[t_]:=Sqrt[f'[t]^2+f[t]^2]
thisLength=NIntegrate[length[t],{t,0,th0}];
p1=ParametricPlot[{x[t],y[t]},{t,0,th0},
PlotStyle->Red,PlotLabel->StringJoin["Length =",ToString[thisLength,InputForm]],
PlotRange->{{-1,1},{-1,1}}]

Here it is as a manipulate command:

Manipulate[
Module[{},
thisLength=NIntegrate[length[t],{t,0,θ}];
p1=ParametricPlot[{x[t],y[t]},{t,0,2Pi},PlotLabel->StringJoin["Length =",ToString[thisLength,InputForm]]];
p2=ParametricPlot[{x[t],y[t]},{t,0,θ},
PlotStyle->{Thickness[.02],Red},
PlotRange->{{-1,1},{-1,1}}];
Show[p1,p2]
],{θ,.0001,Pi}
]

And if Andy wants to peel an orange in an optimal way....

Here is a curve that reminds me of my solution to the orange peeling problem, if your orange is flat and of infinite extent (assume small spherical elephants!:). (Aren’t all of your oranges flat and infinite?) Consider "the Involute of a circle": r^2=θ^2+1

p1=PolarPlot[Sqrt[θ^2+1],{θ,0,6π},AspectRatio->1];
p2=PolarPlot[-Sqrt[θ^2+1],{θ,0,6π},AspectRatio->1, PlotStyle->Red];
Show[p1,p2]

I think, however, that my hero Archimedes beat me to the solution. I’m sure that he peeled a lot of oranges. The spiral of Archimedes: r=aθ

p1=PolarPlot[θ/(2π),{θ,0,6π},AspectRatio->1];
p2=PolarPlot[-θ/(2π),{θ,0,6π},AspectRatio->1, PlotStyle->Red];
Show[p1,p2]

Nonetheless I hold out hope for my peeling, which is piecewise half-circles:

f[t_]=-Cos[t];
g[t_]=Sin[t];
p1=Show[
Table[
ParametricPlot[
{n (f[t]-(1+(-1)^n)/(2n)),n*g[t]},
{t,(n-1) Pi,n Pi},
Ticks->None,
PlotRange->{{-6,6},{-6,6}},
PlotStyle->Red
],
{n,1,5,1}
]
]

Here it is as a manipulate command:

Manipulate[
Module[{cx,cy,n},
n=Ceiling[time/Pi];
cx=n (f[time]-(1+(-1)^n)/(2n));
cy=n*g[time];
Show[
p1,
ParametricPlot[{f[t]-1,g[t]},{t,-Pi,0},PlotStyle->Green],
Table[
ParametricPlot[
{(n+1) (f[t]-(1+(-1)^n)/(2(n+1))),(n+1)g[t]},
{t,(n-1) Pi,Min[n Pi,time]},
Ticks->None,
PlotRange->{{-6,6},{-6,6}},
PlotStyle->Green
],
{n,1,Ceiling[time/Pi],1}
],
ParametricPlot[{f[t]+cx,g[t]+cy},{t,0,2Pi}]
]
],{time,0.01,5*Pi}
]