This is a simple SIR model, built to reproduce the one that we made in InsightMaker based on an MAA on-line SIR project:

https://www.maa.org/press/periodicals/loci/joma/the-sir-model-for-spread-of-disease-the-differential-equation-model

Andy Long
Spring, 2020

Starting parameters from the project lead to the following graphic:

Clear["Global`*"]

Manipulate[
lv=
NDSolve[
{(*  susceptible: *)
sus'[t]==-InfectionRate sus[t] inf[t],
(* infected: *)
inf'[t]==InfectionRate sus[t] inf[t]-RecoveryRate inf[t],
(* recovered: *)
rec'[t]==RecoveryRate inf[t],
sus[0]==1-infected,
inf[0]==infected,
rec[0]==0
},
{sus[t],inf[t],rec[t]},
{t,0,tend}];
Plot[Evaluate[{sus[t],inf[t],rec[t]}/.lv],{t,0,tend},
PlotRange->All,
AxesOrigin->{0,0},PlotStyle->{{Blue,Thick},{Red,Thick},{Yellow,Thick}},
PlotLabel->"SIR Model Population Densities",
AxesLabel->{"Days","Density"},
PlotLegends->{"s(t)","i(t)","r(t)"}
],
{{lv,{}},None},
{{tend,150},2,200,10},
{{infected,1.27/1000000},0,1,.001},
{{RecoveryRate,1/3},0.0,.7,.01},
{{InfectionRate,0.5},0,1,.001}
]