This is a non-dimensionalized version of the wolves and moose of Isle Royale, Michigan, with more realistic population dynamics for the moose (logistic growth). 

We began with the InsightMaker model which is available at
https://insightmaker.com/insight/2068/Isle-Royale-Predator-Prey-Interactions

Then I  non-dimensionalized the system, by dividing populations by a reference quantity. In the case of the moose it was the carrying capacity of moose in the absence of wolves. In the case of the wolves, it was the number of “initial wolves”, at time t=0. That way, the wolf population always starts at 1.

In the end we scale time, by dividing both equations in the system by the birth parameter for the moose (which had better never be zero!). The remaining parameters are then relative to the rate of birth of moose, rather than rates in time; and time is measured in units of τ=(Subscript[b, m])*t.

I have two different models -- one using just mass-action dynamic, and one incorporating the kill rate, modeled as Sqrt[m(t)/w(t)]/10, from 
http://www.isleroyalewolf.org/http%3A//www.cpc.ncep.noaa.gov/products/precip/CWlink/pna/nao.shtml

Andy Long
Spring, 2018

Thanks to:
https://mathematica.stackexchange.com/questions/74214/the-lotka-volterra-predator-prey-model

Perhaps helpful stuff.... from other sources: http://reference.wolfram.com/language/tutorial/NDSolveDelayDifferentialEquations.html

Clear everything possibly in our way:

Clear["Global`*"]

Now let’s get the actual wolf/moose data, extracted from a much more extensive data set, available from 
http://www.isleroyalewolf.org/data/data/home.html

IsleRoyale=Import["http://ceadserv1.nku.edu/longa//classes/mat375/data/isleroyale_graph_data_28Dec2011.csv"];

A look at the actual data:

year=Rest[IsleRoyale[[All,1]]];
minYear=Min[year]
year=year-minYear;
wolves=Rest[IsleRoyale[[All,2]]];
moose=Rest[IsleRoyale[[All,3]]];
ListPlot[Transpose[{year+minYear,moose}]]
ListPlot[Transpose[{year+minYear,wolves}]]
(* Do you see a ring-around-the-rosey? *)
ListPlot[Transpose[{moose,wolves}]]

MooseBirthRate=.68

Manipulate[
lv=
NDSolve[
{(*  moose: *)
m'[t]==m[t]((1-m[t]) -MooseDeathRatio/MooseBirthRate* w[t]) , (* 
*12*Sqrt[m[t]/w[t]/100] 
*)
(* wolves: *)
w'[t]==w[t](WolfBirthRatio/MooseBirthRate m[t] -WolfDeathRatio/MooseBirthRate),
m[0]==mo,
w[0]==1
},
{m[t],w[t]},
{t,0,tend}];
p1=ListPlot[Table[Style[{year[[t]],moose[[t]]/3000},Hue[t/Length[moose]]],{t,1,Length[moose],1}],PlotStyle->PointSize[Medium]];
p2=Plot[Evaluate[{(w[t])}/.lv],{t,0,tend},
PlotRange->All,AxesOrigin->{0,0}];
p3=Plot[Evaluate[{m[t]}/.lv],{t,0,tend},
PlotRange->All,AxesOrigin->{0,0}];
(* Print[((1-WolfDeathRatio/WolfBirthRatio)/(10*MooseDeathRatio))^2/(WolfDeathRatio/WolfBirthRatio)]; *)
p4=Plot[((1-WolfDeathRatio/WolfBirthRatio)/(10*MooseDeathRatio))^2/(WolfDeathRatio/WolfBirthRatio),{t,0,tend},PlotRange->All,AxesOrigin->{0,0}];
p5=Plot[WolfDeathRatio/WolfBirthRatio,{t,0,tend},
PlotRange->All,AxesOrigin->{0,0}];
p6=Plot[(1-WolfDeathRatio/WolfBirthRatio)/MooseDeathRatio*MooseBirthRate,{t,0,tend},
PlotRange->All,AxesOrigin->{0,0}];
Show[p2,p3,p4,p5,p6],
{{lv,{}},None},
{{tend,20},1,300,5},
{{WolfDeathRatio,.36},.01,WolfBirthRatio*.95,.01},
{{WolfBirthRatio,1.6},.1,2,.1},
{{MooseDeathRatio,1},.1,3,.1},
{{mo,.4},.1,1.5,.1}
]

Manipulate[
lv=
NDSolve[
{(*  moose: *)
m'[t]==m[t]((1-m[t]) - MooseDeathRatio/MooseBirthRate*1.2*Sqrt[m[t]*w[t]] ) ,
(* MooseDeathRatio/MooseBirthRate* *) 
(* wolves: *)
w'[t]==w[t](WolfBirthRatio/MooseBirthRate m[t] -WolfDeathRatio/MooseBirthRate),
m[0]==mo,
w[0]==1
},
{m[t],w[t]},
{t,0,tend}];
p2=Plot[Evaluate[{(w[t])}/.lv],{t,0,tend},
PlotRange->All,AxesOrigin->{0,0}];
p3=Plot[Evaluate[{m[t]}/.lv],{t,0,tend},
PlotRange->All,AxesOrigin->{0,0}];
(* Print[((1-WolfDeathRatio/WolfBirthRatio)/(10*MooseDeathRatio))^2/(WolfDeathRatio/WolfBirthRatio)]; *)
p5=Plot[{((1-WolfDeathRatio/WolfBirthRatio)*10*MooseBirthRate/(12*MooseDeathRatio))^2/(WolfDeathRatio/WolfBirthRatio),WolfDeathRatio/WolfBirthRatio},{t,0,tend},
PlotRange->All,AxesOrigin->{0,0},PlotLabels->{"Wolf Asymptote","Moose Asymptote"}];
Show[p2,p3,p5],
{{lv,{}},None},
{{tend,25},20,2000,10},
{{WolfDeathRatio,.22},.01,WolfBirthRatio*.95,.01},
{{WolfBirthRatio,.5},.1,2,.1},
{{MooseDeathRatio,.9},.1,3,.1},
{{wo,22},2,55,1},
{{K,3000},200,6000,100},
{{mo,.8},.1,1.5,.1}
]